// 20150818 Akira Muto 

///////////// Specifying the data folders and making a list of subfolders

source_dir = getDirectory("Please select the data folder.");
dest_dir = getDirectory("Please select a folder where the results will be saved.");

print("Data folder:"+source_dir);
print("Results folder:"+dest_dir);

sub_dir_list = getFileList(source_dir);

//Needed for WINDOWS OS. The file separator is "\\" in WIndows7, "/" in MacOS
for(i=0; i<sub_dir_list.length; i++){sub_dir_list[i]=replace(sub_dir_list[i], "/", File.separator);} 


/////////////　Batch processing to work on all the subfolders in the data folder 

for(k=0; k<sub_dir_list.length; k++){ 

print("sub_dir_list["+k+"]: "+sub_dir_list[k]);


/////////////　Obtain the file names of the sequential JPEG images in the subfolder 

imagelist = getFileList(source_dir+sub_dir_list[k]);

for(i=0; i<imagelist.length; i++){

	print("imageList["+i+"]: "+imagelist[i]);

	}


/////////////　Read the JPEG image sequence in a subfolder.

imagefile=replace(source_dir+sub_dir_list[k]+imagelist[imagelist.length-1],"/",File.separator);

print("The last frame:"+imagefile);//Just to check.

run("Image Sequence...", "open=imagefile");
rowimage = getImageID();


/////////////　Make binary images. You need to use your own values for Threshold.

selectImage(rowimage);
setThreshold(0,121);//Use your own values for your image data 
run("Make Binary", "method=Default background=Dark thresholded remaining black");


/////////////　Particle analysis. You need to use your own values for the  Size and Circularity

run("Invert", "stack");
run("Set Measurements...", "area center shape redirect=None decimal=3");

run("Analyze Particles...", "size=30-160 circularity=0.2-1.00 show=Masks display clear summarize stack");


/////////////// Obtain the center of mass (XM and YM) in the Results window

headings = split(String.getResultsHeadings);

x=newArray(nResults);
y=newArray(nResults);

	for (row=0; row<nResults; row++) {
		x[row]=parseInt(getResult(headings[1],row));
		y[row]=parseInt(getResult(headings[2],row));
	}


/////////////// Draw a dot at (XM, YM) in the frame for all particles

open(source_dir+sub_dir_list[k]+imagelist[imagelist.length-1]);
run("RGB Color");
lastFrame=getTitle;

run("Point Tool...", "mark=2 label selection=green");

for(i=0;i<nResults;i++){

	selectWindow(lastFrame);
	setForegroundColor(255-255*i/(nResults-1),255,0);//Change the color from yellow (255,255,0) to green (0,255,0)
	makePoint(x[i], y[i]);
	run("Draw");
}

saveAs("Jpeg", dest_dir+replace(sub_dir_list[k],File.separator,"_")+"Plot"+".jpg");


////////////// Save Results and close image windows 

while (nImages>0) {selectImage(nImages); close();}//Closing all the image windows 

resultsfilename=sub_dir_list[k]+"Results.txt";
resultsfilename=replace(resultsfilename,File.separator,"_");
saveAs("Results", dest_dir+resultsfilename);
selectWindow("Results");run("Close");

print("Results was saved as "+dest_dir+resultsfilename);


SummaryWindowName="Summary of "+sub_dir_list[k];
SummaryWindowName=substring(SummaryWindowName,0,lengthOf(SummaryWindowName)-1);//To remove the last character (which is the file separator)

summaryfilename=sub_dir_list[k]+"Summary.txt";
summaryfilename=replace(summaryfilename, File.separator,"_");

selectWindow(SummaryWindowName); 
saveAs("Text", dest_dir+summaryfilename);
selectWindow(SummaryWindowName); run("Close");

print("Summary was saved as "+dest_dir+summaryfilename);


///////////// End of the batch processing

}//The end of the for-loop